2sk135, 2sj50 Spice

[peranders]

I have searched but I can't find any SPICE data for 2SK135 and 2SJ50. Anyone who can help me?

While we're at it I also want 2SK1058 and 2SJ162 and 2SK1530, 2SJ201.

Thanks.

 

[Christer]

Models for 2SJ162 and 2SK1058 has already been posted on
the forum before:

http://www.diyaudio.com/forums/showthread.php?postid=26926#post26926


Models for the Exicon equivalent of these devices (much
cheaper than buying the Hitachis at Elfa, and better also
according to some people).
http://www.diyaudio.com/forums/showthread.php?postid=171238#post171238

 

[peranders]

Thanks Christer but I'm mostly interested in the old K135 and J50 just for comparing only so if anyone has SPICE data (if they exists?) for these oldies I would be greatful.

 

[Fred Dieckmann]

I have them

Of course they exist........

*SRC=2SJ50;MSJ50;MOSFETs P;Power >100V;160V 7A
*SYM=POWMOSP
.SUBCKT MSJ50 10 20 40
* TERMINALS: D G S
* Hitachi 160 Volt 7 Amp .171 ohm P-Channel Power MOSFET 08-07-1993


*SRC=2SK135;MSK135;MOSFETs N;Power >100V;160V 7A
*SYM=POWMOSN
.SUBCKT MSK135 10 20 40
* TERMINALS: D G S
* Hitachi 160 Volt 7 Amp .171 ohm N-Channel Power MOSFET 08-07-1993

 

[Netlist]

.MODEL 2SK135 NMOS (VTO=-825.323M KP=20U L=2U W=21.5246M GAMMA=0 PHI=600M
+ LAMBDA=5.32872M CBD=2.89514N IS=10F CGSO=1.13517N CGDO=1.13517N TOX=0 NSUB=0
+ TPG=1 UO=600 RG=50 RDS=1MEG )

.MODEL 2SJ50 PMOS (VTO=1.01702 KP=20U L=2U W=19.7496M GAMMA=0 PHI=600M
+ LAMBDA=15.4837M CBD=2.96862N IS=10F CGSO=1.13517N CGDO=1.13517N TOX=0 NSUB=0
+ TPG=1 UO=600 RG=50 RDS=1MEG )

/Hugo

 

[davygrvy]

An old thread, but shows up in Google so I thought I'd complete it:

*SRC=2SJ50;MSJ50;MOSFETs P;Power >100V;160V 7A
*SYM=POWMOSP
.SUBCKT 2SJ50 10 20 40
* TERMINALS: D G S
* Hitachi 160 Volt 7 Amp .171 ohm P-Channel Power MOSFET 08-07-1993
M1 1 2 3 3 DMOS L=1U W=1U
RD 10 1 80.4M
RS 30 3 5.28M
RG 20 2 15.4
CGS 2 3 860P
EGD 12 0 1 2 1
VFB 14 0 0
FFB 1 2 VFB 1
CGD 13 14 513P
R1 13 0 1
D1 12 13 DLIM
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 10 3 DSUB
LS 30 40 7.5N
.MODEL DMOS PMOS (LEVEL=3 THETA=60M VMAX=533K ETA=5.5M VTO=-.34 KP=.599)
.MODEL DCGD D (CJO=513P VJ=.6 M=.68)
.MODEL DSUB D (IS=29N N=1.5 RS=61.4M BV=160 CJO=1.12N VJ=.8 M=.42 TT=252N)
.MODEL DLIM D (IS=100U)
.ENDS


*SRC=2SK135;MSK135;MOSFETs N;Power >100V;160V 7A
*SYM=POWMOSN
.SUBCKT 2SK135 10 20 40
* TERMINALS: D G S
* Hitachi 160 Volt 7 Amp .171 ohm N-Channel Power MOSFET 08-07-1993
M1 1 2 3 3 DMOS L=1U W=1U
RD 100 1 80.4M
RS 30 3 5.28M
RG 20 2 21.4
CGS 2 3 590P
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 128P
R1 13 0 1
D1 12 13 DLIM
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 100 DSUB
LS 30 40 12.5N
LD 10 100 5N
.MODEL DMOS NMOS (LEVEL=3 THETA=80M VMAX=233K ETA=2M VTO=.25 KP=.817)
.MODEL DCGD D (CJO=128P VJ=.6 M=.68)
.MODEL DSUB D (IS=29N N=1.5 RS=61.4M BV=160 CJO=1.46N VJ=.8 M=.42 TT=252N)
.MODEL DLIM D (IS=100U)
.ENDS