• WARNING: Tube/Valve amplifiers use potentially LETHAL HIGH VOLTAGES.
    Building, troubleshooting and testing of these amplifiers should only be
    performed by someone who is thoroughly familiar with
    the safety precautions around high voltages.

Vacuum Tube SPICE Models

Jump to Latest
#405
dirkwright said:
OK, thanks.

On another tube, I'm having real difficulty finding a tetrode model of a D3A. Can someone direct me to a link or something? thanks.
Click to expand...
I have these two.
Code: 
*           Plate
*           | Screen Grid
*           | | Grid
*           | | | Cathode
*           | | | |
.SUBCKT D3a A S G K ; old model
Eat    at    0    VALUE={.636*ATAN(V(A,K)/20)}                    ; /# is sharpness of knee
Egsg    gsg    0    VALUE={LIMIT(V(S,K)/1+PWRS(V(G,K),1)/.0146+V(A,K)/80000,0,1E6)}    ; s,k/#=peak current  g,k/# is mu  a,k/# is plate res
Egss    gss    0    VALUE={LIMIT(V(S,K)/10000000000+PWRS(V(G,K),1.0)/.03+V(A,K)/80,0,1E6)}    ; separating gsg,gss allows cutoff to be different
Egs2    gs2    0    VALUE={PWRS(V(gsg),1.45)}
Egs3    gs3    0    VALUE={PWRS(V(gss),1.45)}
Ecath     cc        0     VALUE={V(gs2)*V(at)+V(gs3)*V(at)}
Ga         A         K         VALUE={5.4E-5*V(cc)}
Escrn    sc    0    VALUE={V(gs2)*(1.1-V(at))}
Gs         S         K    VALUE={5.0E-5*V(sc)*LIMIT(V(S,K),0,10)/10}
Gg    G    K    VALUE={PWR(LIMIT(V(G,K)+1,0,1E6),1.5)*(1.25-V(at))*450E-6}
Cg1    G    K    8.5p
Cak    A    K    6.5p
Cg1a    G    A    1.1p
.ENDS D3a
Code: 
*                Plate
*                | Screen Grid
*                | | Grid
*                | | | Cathode
*                | | | |
.SUBCKT 7721/D3a A S G K
Ea Gi G value= {-.09} ; grid offset
Eat    at    0    VALUE={.636*ATAN(V(A,K)/15)}                    ; /# is sharpness of knee
Egsg    gsg    0    VALUE={LIMIT(V(S,K)/1+PWRS(V(G,K),1)/.014+V(A,K)/80000,0,1E6)}    ; s,k/#=peak current  g,k/# is mu  a,k/# is plate res mu was too low
Egss    gss    0    VALUE={LIMIT(V(S,K)/10000000000+PWRS(V(G,K),1.0)/.03+V(A,K)/80,0,1E6)}    ; separating gsg,gss allows cutoff to be different
Egs2    gs2    0    VALUE={PWRS(V(gsg),1.4)}
Egs3    gs3    0    VALUE={PWRS(V(gss),1.4)}
Ecath     cc        0     VALUE={V(gs2)*V(at)+V(gs3)*V(at)}
Ga         A         K   VALUE={limit(6.4E-5*V(cc),0,v(a,k)/1.2k)}  ; added knee limit 3-17-10 sb
Escrn    sc    0    VALUE={V(gs2)*(1.1-V(at))}
Gs         S         K    VALUE={limit(9.8E-5*V(sc)*LIMIT(V(S,K),0,10)/10,0,v(a,k)/800)} ; screen current was too low, added limit sb
Gg    G    K    VALUE={PWR(LIMIT(V(G,K)+1,0,1E6),1.5)*(1.25-V(at))*450E-6}
Cg1    G    K    9.5p
Cak    A    K    4.5p
Cg1a    G    A    0.04p
.ENDS D3a
YMMV
 
#407
dirkwright said:
A spice model compatible with Tina would be nice for this tube. Thanks.

I guess it's the same as the 6S45P?
Click to expand...
From Andrei Frolov.
Code: 
* 437A  -  IDH miniature high-transconductance triode
* Gp  P K  VALUE={(m)*limit(()*V(G,K)+V(P,K),0.0,1.0e16)^1.5}
* From WE 437A datasheet - traced on 24-03-02 by AF
.subckt 437A  P G K
    Cgp G P  3.8p
    Ci  G K  11.1p
    Co  P K  1.0p
* Modified Koren model (8 parameters): mean fit error 1.94219 mA
    Gp  P K  VALUE=
+ {(0.04402840226m)*limit(V(P,K)*log(1.0+(-0.3253203784)+exp((2.359465245)+
+ (2.359465245)*((38.12689842)+(-2617.293976m)*V(G,K))*V(G,K)/sqrt((54.35117386)^2+
+ (V(P,K)-(41.98740594))^2)))/(2.359465245),0.0,1.0e16)^(1.633336782)}
.ends 437A
 
#409
jackinnj said:
Here are the params for the 832, Vg2=250:

All Data Points: MU=6.27 KP=44.84 EX=1.55 KVB=36.1 KG1=5476
For Vak>= 50: MU=6.86 KP=28.01 EX=1.55 KVB=24.7 KG1=4795
For Vak>=100: MU=6.90 KP=27.40 EX=1.55 KVB=38.1 KG1=4614

All of the above are dependent upon the number of points, where you choose to select them from, and how you describe the error term being minimized. This was a pretty quick rendering of the datasheet into Excel, so ymmv.
Click to expand...

Hello, I am interested in tracing out a Chinese 832a tube amp into Multisim but I can't find any tube models in multisim... do you know where I can get the 832a and 6n2p or 12ax7 tube model? is there software I can get that will have all these already in the library?
 
#411
tube simulation

Is it possible to hire someone to redraw a tube amp into simulation software. I have a chinese 832a tube amp and would like to have someone make a project file. The amp is very small design. I don't think I have the skills to be able to do this on my own.

PM me if you are interested in this task.
 
#413
Hi,
Yes, 6p36s is really interesting tube. It's size compared to 6L6 and EL34 is huge.
It's heater current is specified to be 2 amps. All these refer to high power tube, but still the max. Pa + Pg2 is 16 W or 23 W depending on how you read the specification.

I think it has much more potential than one can see at first glance.

But mainly I am looking for the pentode model and hopefully find it.
 
#414
Hi,

I would also be interested on a Spice/Simetrix model for 6P36S, as I'm currently experimenting a PP amplifier with it, and would like to run some simulations.

As artosalo said, it's a rather interesting tube, seems to be strong like a tank, and I believe that there might be some quite nice performance to extract from in!

Thank you!
 
#415
6P36S Pentode Model

Try this one, not perfect match but should be good enough for testing purpose:

Code: 
*
* Generic pentode model: 6P36S_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Thanks to Tooru Kuroda.
* Version 3.10, Generated on Fri Apr 04 13:52:24 2014
*                Plate
*                | Screen Grid
*                | | Control Grid
*                | | | Cathode
*                | | | |
.SUBCKT 6P36S_AN A G2 G1 K
.param GG  {(V(G1,K)+-0.99999573)}
.param EP  {URAMP(V(A,K))}
.param EG  {URAMP(V(G1,K))}
.param EG2 {URAMP(V(G2,K))}
.param M1  {((0.028278791*EG2)**-0.28060747)}
.param M2  {((0.84240913*URAMP(GG+EG2/5.5727583))**1.7806075)}
.param P   {(0.004800129*URAMP(GG+EG2/6.6152634)**1.5)}
.param IK  {(U(GG)*P+(1-U(GG))*0.0029989754*M1*M2)}
.param IG  {(0.0024000645*EG**1.5*(EG/(EP+EG)*1.2+0.4))}
.param IK2 {((IK-IG)*(1-0.4*(EXP(-EP/(EG2+1e-10)*15)-EXP(-15))))}
.param IG2T {(IK2*(0.972078544*(1-EP/(EP+10))**1.5+0.027921456))}
.param IK3 {(IK2*(EP+936.25)/(EG2+936.25))}
.param IK4 {(IK3-URAMP(IK3-(0.0035286371*(EP+URAMP(EG2-EP))**1.5)))}
.param IP  {URAMP(IK4-IG2T-URAMP(IK4-IG2T-(0.0035286371*EP**1.5)))}
BIAK A  K I=IP+1e-10*V(A,K)
BIG2 G2 K I=URAMP(IK4-IP)
BIGK G1 K I=IG
* CAPS
CGA G1 A  1p
CGK G1 K  19.2p
C12 G1 G2 12.8p
CAK A  K  170p
.ENDS
 
#418
UPDATE: it worked for me in Simetrix, I had to change the line endings from Mac (CR) to Dos/Windows (CR/LF).

One single point to comment on.
The inter-electrode capacitances: there is a russian/english datasheet which specifies different values: CG1-K = 32pF, CG1-A <= 1pF, CA-K <= 21pF.


Regards!
 
Last edited:
#419
artosalo said:
This 6P36S_AN does not work with LTspice. I just tried it.
Click to expand...
This works in LTSpice. I may have made a mistake or two, as I haven't tested it thoroughly. So beware... 😀
Code: 
*
* Generic pentode model: 6P36S_AN
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Fri Apr 04 13:52:24 2014
*                Plate
*                | Screen Grid
*                | | Control Grid
*                | | | Cathode
*                | | | |
.SUBCKT 6P36S_AN A G2 G1 K
BGG   GG   0 V=V(G1,K)+-0.99999573
BM1   M1   0 V=(0.028278791*(URAMP(V(G2,K))+1e-10))**-0.28060747
BM2   M2   0 V=(0.84240913*(URAMP(V(GG)+URAMP(V(G2,K))/5.5727583)))**1.7806075
BP    P    0 V=0.004800129*(URAMP(V(GG)+URAMP(V(G2,K))/6.6152634))**1.5
BIK   IK   0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0029989754*V(M1)*V(M2)
BIG   IG   0 V=0.0024000645*URAMP(V(G1,K))**1.5*(URAMP(V(G1,K))/(URAMP(V(A,K))+URAMP(V(G1,K)))*1.2+0.4)
BIK2  IK2  0 V=V(IK,IG)*(1-0.4*(EXP(-URAMP(V(A,K))/URAMP(V(G2,K))*15)-EXP(-15)))
BIG2T IG2T 0 V=V(IK2)*(0.972078544*(1-URAMP(V(A,K))/(URAMP(V(A,K))+10))**1.5+0.027921456)
BIK3  IK3  0 V=V(IK2)*(URAMP(V(A,K))+936.25)/(URAMP(V(G2,K))+936.25)
BIK4  IK4  0 V=V(IK3)-URAMP(V(IK3)-(0.0035286371*(URAMP(V(A,K))+URAMP(URAMP(V(G2,K))-URAMP(V(A,K))))**1.5))
BIP   IP   0 V=URAMP(V(IK4,IG2T)-URAMP(V(IK4,IG2T)-(0.0035286371*URAMP(V(A,K))**1.5)))
BIAK  A    K I=V(IP)+1e-10*V(A,K)
BIG2  G2   K I=URAMP(V(IK4,IP))
BIGK  G1   K I=V(IG)
* CAPS
CGA   G1  A  1.1p
CGK   G1  K  10.8p
C12   G1  G2 7.2p
CAK   A   K  8p
.ENDS
 
Last edited:
You must log in or register to reply here.
Top Bottom